home *** CD-ROM | disk | FTP | other *** search
/ Die Ultimative Software-P…i Collection 1996 & 1997 / Die Ultimative Software-Pakete CD-ROM fur Atari Collection 1996 & 1997.iso / p / pov / povlisti.ngs / esp01.pov < prev    next >
Encoding:
Text File  |  1992-07-20  |  2.4 KB  |  97 lines
  1. // Persistence Of Vision raytracer version 1.0 sample file.
  2.  
  3. // PolyWood.pov - Wooden polyhedron hollowed by a sphere
  4. // on a grassy hilly lawn.  Shows how easy it is to
  5. // create interesting shapes with CSG operations
  6. // and simple primitive shapes.
  7. // By Eduard [esp] Schwan, 6/23/92
  8.  
  9. include "shapes.inc"
  10. include "colors.inc"
  11. include "textures.inc"
  12.  
  13. // Moi
  14. camera
  15. {
  16.   location <-3.5  1  -12.0>
  17.   direction <0.0 0.0  1.0>
  18.   up  <0.0  1.0  0.0>
  19.   right <1.33 0.0 0.0>
  20.   look_at <0 0 0>
  21. }
  22.  
  23. // Some Light
  24. object
  25. {
  26.   light_source { <20 10 -40> color White }
  27. }
  28.  
  29. // The Cloudy Blue Sky
  30. object
  31. {
  32.   sphere { <0 0 0> 10000  }
  33.   texture { Bright_Blue_Sky  scale <4000 600 1000> }
  34. }
  35.  
  36. // The Hilly Grassy Land
  37. object
  38. {
  39.   plane { <0.0 1.0 0.0> -4.1  }
  40.   texture
  41.   {
  42.     0.025  // a little randomness to hide the rather severe color banding
  43.     color red 0.2 green 1.0 blue 0.4
  44.     bumps 0.5
  45.     frequency 100
  46.     scale <10 10 10>
  47.     ambient 0.1
  48.     diffuse 0.7
  49.     roughness 1
  50.   }
  51. }
  52.  
  53. // The Wooden Polyhedron
  54. // The idea here is to take a few cubes rotated at 45 degrees
  55. // along different axes from each other and intersect them,
  56. // thus cutting some corners.  Then we carve out the center
  57. // with a slightly oversized sphere, which protrudes slightly
  58. // through the sides, cutting portholes in the facets of the
  59. // polyhedron.  Then we get out the wooden paint..
  60. object
  61. {
  62.   intersection
  63.   {
  64.     // polyhedron
  65.     box { <-4 -4 -4> <4 4 4> }
  66.     box { <-4 -4 -4> <4 4 4>  rotate <45  0  0> }
  67.     box { <-4 -4 -4> <4 4 4>  rotate < 0 45  0> }
  68.     // Add small amount to box to account for normal numerical innacurracies
  69.     box { <-4.0001 -4.0001 -4.0001> <4.0001 4.0001 4.0001>  rotate < 0  0 45> }
  70.     // hollow it out
  71.     sphere { <0 0 0> 4.25 inverse }
  72.   }
  73.   // semi-dark wood with dark greenish rings
  74.   texture
  75.   {
  76.     wood
  77.     turbulence 0.04
  78.     colour_map
  79.     {
  80.       [0.0 0.4  color red 0.8 green 0.4 blue 0.2
  81.             color red 0.8 green 0.4 blue 0.1]
  82.       [0.4 0.5  color red 0.1 green 0.3 blue 0.1
  83.             color red 0.1 green 0.3 blue 0.2]
  84.       [0.5 0.8  color red 0.1 green 0.3 blue 0.2
  85.             color red 0.8 green 0.4 blue 0.1]
  86.       [0.8 1.001  color red 0.8 green 0.4 blue 0.1
  87.             color red 0.8 green 0.4 blue 0.2]
  88.     }
  89.     scale <0.2  0.2  1>
  90.     rotate <45  0  5>
  91.     translate <2  2  -4>
  92.     ambient 0.15
  93.     diffuse 0.6
  94.   }
  95. }
  96. // ttfn!
  97.